//Fichier include des textures de Mercenaires destiné à la génération automatisée d'un maximum de textures
	#macro Pig_5colors_Wrinkles( Multiplicateur, Col1, Col2, Col3, Col4, Col5)
		pigment{wrinkles color_map{ 
                                   [0.0 Col3 * Multiplicateur]  
                                   [0.125 Col2 * Multiplicateur]
                                   [0.25 Col1 * Multiplicateur] 
                                   [0.375 Col2 * Multiplicateur]
                                   [0.5 Col3 * Multiplicateur]
                                   [0.675 Col4 * Multiplicateur]
                                   [0.75 Col5 * Multiplicateur] 
                                   [0.875 Col4 * Multiplicateur]
                                   [1.0 Col3 * Multiplicateur]
                                  }
                    scale 0.005
        }
	#end


//Browns
	#macro T_5var_Wrinkles( Multiplicateur, Col1, Col2, Col3, Col4, Col5)
		texture{pigment{wrinkles color_map{ 
                                       [0.0 Col3 * Multiplicateur]  
                                       [0.125 Col2 * Multiplicateur]
                                       [0.25 Col1 * Multiplicateur] 
                                       [0.375 Col2 * Multiplicateur]
                                       [0.5 Col3 * Multiplicateur]
                                       [0.675 Col4 * Multiplicateur]
                                       [0.75 Col5 * Multiplicateur] 
                                       [0.875 Col4 * Multiplicateur]
                                       [1.0 Col3 * Multiplicateur]
                                      }
                    scale 0.005
                    }
           }
	#end
	//Brown grounds definitions made with macros
	#declare T_brown1 = T_5var_Wrinkles(1   ,Brown1_srgb, Brown2_srgb, Brown3_srgb, Brown4_srgb, Brown5_srgb)
	#declare T_brown2 = T_5var_Wrinkles(1.12  ,Brown1_srgb, Brown2_srgb, Brown3_srgb, Brown4_srgb, Brown5_srgb)
	#declare T_brown3 = T_5var_Wrinkles(1.225 ,Brown1_srgb, Brown2_srgb, Brown3_srgb, Brown4_srgb, Brown5_srgb)
	#declare T_brown4 = T_5var_Wrinkles(1.345 ,Brown1_srgb, Brown2_srgb, Brown3_srgb ,Brown4_srgb, Brown5_srgb) 
	
	//Pigment here
	#declare Pig_brown2 = Pig_5colors_Wrinkles(1.12 ,Brown1_srgb, Brown2_srgb, Brown3_srgb, Brown4_srgb, Brown5_srgb)
	#declare Pig_brown3 = Pig_5colors_Wrinkles(1.225 ,Brown1_srgb, Brown2_srgb, Brown3_srgb, Brown4_srgb, Brown5_srgb)
//-----------------------------------
	
//Gray Rocks textures
	#declare T_rocks2 = texture{
							pigment{ color srgb 0.6 }
							normal { agate bump_size 0.75 scale 0.2}
							finish{specular 0.1 roughness 0.1 }
						   }
	#declare T_OldRocks2 = T_5var_Wrinkles(<1.3, 1.15, 1>, color srgb 0.8, color srgb 0.7, color srgb 0.6, color srgb 0.5, color srgb 0.4)

	#declare T_rocksA2 = texture{ T_OldRocks2
									  finish{specular 0.2 diffuse 0.4 ambient 0.24} 
									  normal{granite 0.6 scale 0.1}
									 }
						   
//-----------------------------------
	#macro T_3var_Wrinkles(multiplicateur, Col1,Col2,Col3)
		texture{pigment{wrinkles color_map{ 
                                       [0.0 Col2*multiplicateur]  
                                       [0.25 Col3*multiplicateur] 
                                       [0.5 Col2*multiplicateur]
                                       [0.75 Col1*multiplicateur] 
                                       [1.0 Col2*multiplicateur]
                                      }
                    scale 0.005
                    }
           }
	#end
	#macro Pig_3colors_Wrinkles(multiplicateur, Col1,Col2,Col3)
		pigment{wrinkles color_map{ 
                                   [0.0 Col2*multiplicateur]  
                                   [0.25 Col3*multiplicateur] 
                                   [0.5 Col2*multiplicateur]
                                   [0.75 Col1*multiplicateur] 
                                   [1.0 Col2*multiplicateur]
                                  }
                    scale 0.005
         }
	#end
	//Grass textures
	#declare T_grass_bright = T_3var_Wrinkles(1.4, GrassColBright, GrassColMedium, GrassColDark)
							  
	#declare T_grass_medium = T_3var_Wrinkles(1.2, GrassColBright, GrassColMedium, GrassColDark)
	#declare T_grass_dark = T_3var_Wrinkles(1, GrassColBright, GrassColMedium, GrassColDark)
	
	#declare Pig_mediumGrass = Pig_3colors_Wrinkles(1.2, GrassColBright, GrassColMedium, GrassColDark)
	
#declare T_brightWater = T_5var_Wrinkles( 1.6, Blue1, Blue2, Blue3, Blue2, Blue1)                                                                                                                           
#declare T_mediumWater = T_5var_Wrinkles( 1.3, Blue1, Blue2, Blue3, Blue2, Blue1)
#declare T_darkWater = T_5var_Wrinkles( 1, Blue1, Blue2, Blue3, Blue2, Blue1)
#declare T_darkestWater = T_5var_Wrinkles( 0.8, Blue1, Blue2, Blue3, Blue2, Blue1)

//------------------------------------
#declare T_pathBright = texture{pigment{ PathBrightCol } normal{agate 0.4 scale 0.1} }
#declare T_pathMedium = texture{pigment{ PathMediumCol } normal{agate 0.4 scale 0.1} }
#declare T_pathDark   = texture{pigment{ PathDarkCol } normal{agate 0.4 scale 0.1} }

//------------------------------------
//Sand texture
#declare T_brightSand = texture {
									pigment {color srgb < 1 * 1.3, 0.9 * 1.3, 0.65 * 1.3 > }
									normal {granite 0.2 scale 0.02}
									finish {brilliance 1.6 specular 0.3 }
								  }
#declare T_mediumSand = texture {
									pigment {color srgb < 1 * 1.15, 0.9 * 1.15, 0.65 * 1.15 > }
									normal {granite 0.2 scale 0.02}
									finish {brilliance 1.6 specular 0.3 }
								  }
#declare T_darkSand = texture {
									pigment {color srgb < 1, 0.9, 0.65> }
									normal {granite 0.2 scale 0.02}
									finish {brilliance 1.6 specular 0.3	}
								  }

//--------------------------------------
//Texture of slopes version 1
//T scène landscape
#declare T_roche1 = texture {pigment {agate color_map {
                                                     [0.2 color srgb <0.55, 0.50, 0.50> ]
                                                     [0.6 color srgb <0.75, 0.50, 0.60> ]
                                                     [1.0 color srgb <0.70, 0.60, 0.60> ]
                                                    }
                                        scale 0.1 warp { turbulence 0.5 }
                                   }
                            finish {specular 0.2 diffuse 0.4 ambient 0.24}
                            normal {granite 0.6 scale 0.5}
                           }
                           
//---------------------------------------
//Texture of concrete with steep transition grayscale image for alpha channels
#declare T_concrete = 
texture{
	pigment{ ConcreteAverageCol } 
	normal{ agate bump_size 0.5 } 
	scale 0.1
}                       

//--------------------------------------
#declare BlackMixPig = Pig_5colors_Wrinkles(1, DarkColA, DarkColB, DarkColC, DarkColB, DarkColA)
#declare BurntViewSize = 2.2;
#declare BurntSquareNum = 2;