//The fuel reserve for the kameri space ship

#declare FuelResRadius = 3;
#declare FuelResSmallRadius = 0.65;
#declare FuelResWidth = 12;
#declare FuelResTenantsWidth = 0.2;
#declare FuelResTenantsPos = 4;
#declare FuelResTenantsRadius = FuelResRadius + 0.1;
#declare FuelResMitigerRadius = 0.15;
#declare FuelTenantsDepth = -4;

#declare FuelResTexture = 
texture{
	pigment{color srgb < 245 / 255, 240 / 255, 240 / 255 > }
	normal{ agate 0.01 }
	finish{ specular 0.05 roughness 0.1 }
}

#declare FuelResMitigerTexture =
texture{ pigment{ color srgb 0.8 } finish{ metallic specular 0.2 roughness 0.01 } }

#declare FuelReserve =
union{
	union{
		torus{ FuelResRadius - FuelResSmallRadius, FuelResSmallRadius rotate 90 * z translate (-FuelResWidth / 2 + FuelResSmallRadius ) * x }
		torus{ FuelResRadius - FuelResSmallRadius, FuelResSmallRadius rotate 90 * z translate (FuelResWidth / 2 - FuelResSmallRadius ) * x }
		cylinder{ < -FuelResWidth / 2 + FuelResSmallRadius, 0, 0 >, < FuelResWidth / 2 - FuelResSmallRadius, 0, 0 >, FuelResRadius } 
		cylinder{ < -FuelResWidth / 2, 0, 0 >,< 0, 0, 0 >, FuelResRadius - FuelResSmallRadius }
		cylinder{ < FuelResWidth / 2, 0, 0 >,< 0, 0, 0 >, FuelResRadius - FuelResSmallRadius }
		box{ < -FuelResTenantsPos, FuelTenantsDepth, -FuelResTenantsRadius >,< -FuelResTenantsPos - FuelResTenantsWidth, 0, FuelResTenantsRadius > }
		box{ < FuelResTenantsPos, FuelTenantsDepth, -FuelResTenantsRadius >,< FuelResTenantsPos + FuelResTenantsWidth, 0, FuelResTenantsRadius > }
		cylinder{ < -FuelResTenantsPos, 0, 0 >,< -FuelResTenantsPos - FuelResTenantsWidth, 0, 0 >, FuelResTenantsRadius }
		cylinder{ < FuelResTenantsPos, 0, 0 >,< FuelResTenantsPos + FuelResTenantsWidth, 0, 0 >, FuelResTenantsRadius }
		texture{ FuelResTexture }
	}
	union{
		cylinder{ < -FuelResWidth / 2, -FuelResRadius + FuelResSmallRadius + 0.3, 0 >,< -FuelResWidth / 2 - 0.8, -FuelResRadius + FuelResSmallRadius + 0.3, 0 >, FuelResMitigerRadius }
		cylinder{ < -FuelResWidth / 2 - 0.4, -FuelResRadius + FuelResSmallRadius + 0.3, 0 >,< -FuelResWidth / 2 - 0.4, -FuelResRadius + FuelResSmallRadius + 0.6, 0 >, FuelResMitigerRadius / 1.5 }
		cylinder{ < -FuelResWidth / 2 - 0.4, -FuelResRadius + FuelResSmallRadius + 0.6, -0.4 >, < -FuelResWidth / 2 - 0.4, -FuelResRadius + FuelResSmallRadius + 0.6, 0.4 >, FuelResMitigerRadius / 1.5 }
		texture{ FuelResMitigerTexture }
	}
}