//Un objet tente militaire avec des textures genre pantalon treillis
	//Textures
	#declare Gray = srgb 0.867;
	#declare Beige = srgb < 185 / 255, 179 / 255, 130 / 255 >;
	#declare Brown = srgb < 101 / 255, 62 / 255, 53 / 255 >;
	
	#declare Green = srgb < 90 / 255 * 0.8, 131 / 255 * 0.8, 86 / 255 * 0.8 >;
	#declare Brown2 = srgb < 156 / 255, 143 / 255, 98 / 255>;
	
	#declare T_mixTent = texture{pigment{dents color_map{
															   [0.0 Green]//Beige before
															   [0.2 Green]//Beige before
															   [0.21 Brown]//Gray before
															   [0.99 Brown]//Gray before
															   [1.0 Green]//Beige before
															  }
												scale 0.1 rotate 90*x
											 }
									  finish{specular 0.01 roughness 0.05}
									}


	//Géométrie
	#declare EntryRoofY = 0.25+0.5/8;
	
	#declare Stick = cylinder{< 0, 0, -0.5 *9/8>, < 0, EntryRoofY, -0.5 *9/8 >, 0.01 }
	#declare BasePyramid = prism{ conic_sweep linear_spline 1, 0.75, 5 <-0.5, 0.5>, <-0.5, -0.5>, <0.5, -0.5>, <0.5, 0.5>, <-0.5, 0.5> rotate 180*x translate y}
	#declare TopPyramid = prism{ conic_sweep linear_spline 1, 2/3, 5 <-1, 1>, <-1, -1>, <1, -1>, <1, 1>, <-1, 1> rotate 180*x translate y}

	#declare Tent_GeomSolidBlock = union{
						   object{BasePyramid}
						   object{TopPyramid scale 0.5/4/(1/3) translate 0.25*y}
						  }
						  
	#declare Tent_Main = union{
								 difference{
									  object{Tent_GeomSolidBlock}
									  object{Tent_GeomSolidBlock scale 0.98}
									  box{<-0.125, 0, 0>,<0.125, 0.25, -1>}
								   texture{T_mixTent}
						         }
						         box{<-0.25, EntryRoofY, -0.25>,<0.25, EntryRoofY + 0.02 , -0.5*5/4> texture{T_mixTent} }
						        object{Stick pigment{Brown} translate 3/8*0.5*x}
						        object{Stick pigment{Brown} translate -3/8*0.5*x}
						       }
